EMBL-EBI Web Services

This page is read only. You can view the source, but not change it. Ask your administrator if you think this is wrong.
====== WWW::OpenSearch ======

The OpenSearch specification (http://www.opensearch.org/) defines an API for interacting with search engines. This includes:
  * XML format for a document describing how to interact with the search engine.
  * Extensions to [[http://en.wikipedia.org/wiki/RSS|RSS]] (([[http://cyber.law.harvard.edu/rss/rss.html|RSS 2.0 Specification]])) or [[http://en.wikipedia.org/wiki/Atom_(standard)|Atom]] (([[http://www.faqs.org/rfcs/rfc4287.html|RFC4287 - The Atom Syndication Format]])) web feeds to support search results

[[http://www.opensearch.org/|OpenSearch]] is designed to support aggregation of search results and was originally defined to support the [[http://www.a9.com/|A9]] search engine's use of external search engines, without having to develop specific modules to interact with each search engine's API. The provision of interface description documents has lead to the adoption of the OpenSearch description format as the standard for defining search plug-ins in web browsers (e.g. Firefox). To aid in this, the specification defines a method for browsers to discover the search plug-in associated with a web page using a "search" link.

Since [[http://www.opensearch.org/|OpenSearch]] uses web feed to describe results, search results can also be used in [[http://en.wikipedia.org/wiki/Feed_reader|feed readers]], allowing users to get notification of changes in search results.

===== Installation =====

The WWW::OpenSearch modules can be installed by:
  - Using the system package manager install/update the appropriate package, for example libwww-opensearch-perl for Debain based Linux systems (e.g. Ubuntu or Bio-Linux)
  - Using CPAN to install/update WWW::OpenSearch ([[http://search.cpan.org/perldoc?WWW::OpenSearch|CPAN]]).
  - Downloading the WWW::OpenSearch distribution and installing manually:
    * from [[http://search.cpan.org/perldoc?WWW::OpenSearch|CPAN]]
For an overview of the how to install a module see [[..:module_install|Installing Perl Modules]].

===== Using an OpenSearch Description =====

Given an [[http://www.opensearch.org/|OpenSearch]] description a search can easily be performed and a summary of the results retrieved. For example using an [[http://www.opensearch.org/|OpenSearch]] interface to [[http://srs.ebi.ac.uk/|SRS]] to get the entries containing the terms "CFTR mouse" from [[http://www.ebi.ac.uk/uniprot/|UniProtKB]] ([[http://www.ebi.ac.uk/Tools/webservices/workshop/EBIWS_Perl_Exercise/examples/REST/WWW-OpenSearch/srs-uniprot_opensearch.pl|examples/REST/WWW-OpenSearch/srs-uniprot_opensearch.pl]]):
<code perl>
# Load modules
use WWW::OpenSearch;
use XML::Feed;
use XML::Feed::Enclosure;

# The feed returned by SRS uses multiple "enclosure" tags to provide 
# pointers to additional data formats available from SRS. Thus XML::Feed 
# has to be configured to allow multiple encousures per item in the feed
$XML::Feed::MULTIPLE_ENCLOSURES = 1;

# Pointer to OpenSearch XML description for UniProtKB in SRS
my $opensearch_url = 
    'http://srs.ebi.ac.uk/srsbin/cgi-bin/opensearch?db=uniprot';

# Get search interface from the description
my $engine = WWW::OpenSearch->new($opensearch_url);

# The service description contains some general information:
# A name for the search service.
print $engine->description->ShortName, "\n";
# A description.
print $engine->description->Description, "\n";

# Perform a search
my $response = $engine->search('CFTR mouse');

# The result is an RSS (or Atom) feed, with some additional tags. These 
# provide additional details, such as the number of hit found.
print $response->pager->total_entries, ' items found', "\n";

# The results are paged so to get all the results loop through the pages
while($response) {
    # The "item" elements in the feed contain summary data about the hit.
    foreach my $item ($response->feed->items) {
	# For this feed the content is the SRS identifier and the title
	# a description of the entry. 
	print $item->content->body, "\t", $item->title, "\n";
	# A link to the data for the hit. In this case the main entry view
	# in SRS.
	print "\t", $item->link, "\n";
	# Additional data can be associated with the item using an 
	# "enclosure". In this case multiple enclosures are used to 
	# point to other entry formats, e.g. plain text flatfile or 
	# flatfile with hyperlinks. The type provides the MIME type of 
	# the data.
	foreach my $enclosure ($item->enclosure) {
	    print "\t", $enclosure->type, "\t", $enclosure->url, "\n";
	}
    }
    $response = $response->next_page;
}
</code>

\\
^ Up | [[..:..:Perl]] ^ Contents | [[..:..:..:00_Contents|Contents]] |
EMBL-EBI Web Services

EMBL-EBI

Services

Research

Training

Industry

About us
